emlファイルから添付ファイルを抽出するスクリプト２

昨日作ったのを改良しました。

複数のファイルをドラッグ＆ドロップしても大丈夫です。

emlファイルから添付ファイルを抽出するスクリプト

当該スクリプトをvbsファイルに保存し、複数のemlファイルをドラッグ＆ドロップでデスクトップに添付ファイルが保存されます。
添付ファイルは受信日時と添付ファイル名がくっつくようにしています。



*********ここから***************

Option Explicit
Dim EmlFileName
Dim Message,Stm,Attachment,Dtime,strDtime
Dim SaveFile,objShell

Set Message = CreateObject( "CDO.Message" )
Set Stm = CreateObject( "ADODB.Stream" )
Set objShell = WScript.CreateObject("WScript.Shell")

For Each EmlFileName In WScript.Arguments

    'emlファイルを開く
    Stm.Open
    Stm.LoadFromFile EmlFileName

    Message.DataSource.OpenObject Stm, "_Stream"

    '受信日時の取得と変形
    Dtime = Message.ReceivedTime
    strDtime = FormatDateTime(Message.ReceivedTime, vbShortDate)
    strDtime = Replace(strDtime, "/", "")

    '添付ファイルを日時とファイル名を付してデスクトップに保存
    For Each Attachment In Message.Attachments
        SaveFile = objShell.SpecialFolders("Desktop") &_
            "\\" & strDtime & "_" & Attachment.FileName
        Attachment.saveToFile SaveFile
    Next
    Stm.Close
Next

WScript.Echo "終了"

****************ここまで*****************

コメント 2

はじめまして。
VBS初心者ですが、おかげさまでこちらの記事を参考に添付ファイルを保存する事が出来ました。ありがとうございます。
そこで、添付ファイル名の前にメールの件名をつけて保存したいなと自分なりに試行錯誤してみたのですが、なかなかうまくいきません。
よろしければ教えていただけないでしょうか？
お願い致します。
by 匿名 (2015-06-17 14:33) 

新しく記事にします。
by jem (2015-06-18 10:28)